home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_xemacs.idb / usr / freeware / lib / xemacs-20.4 / lisp / packages / fast-lock.el.z / fast-lock.el
Encoding:
Text File  |  1998-05-21  |  32.9 KB  |  755 lines
  1. ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
  2.  
  3. ;; Copyright (C) 1994, 1995, 1996, 1997 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Simon Marshall <simon@gnu.ai.mit.edu>
  6. ;; Keywords: faces files
  7. ;; Version: 3.11.01
  8.  
  9. ;;; This file is part of GNU Emacs.
  10.  
  11. ;; GNU Emacs is free software; you can redistribute it and/or modify
  12. ;; it under the terms of the GNU General Public License as published by
  13. ;; the Free Software Foundation; either version 2, or (at your option)
  14. ;; any later version.
  15.  
  16. ;; GNU Emacs is distributed in the hope that it will be useful,
  17. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19. ;; GNU General Public License for more details.
  20.  
  21. ;; You should have received a copy of the GNU General Public License
  22. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24. ;; Boston, MA 02111-1307, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;; Lazy Lock mode is a Font Lock support mode.
  29. ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  30. ;; properties from automatically saved associated Font Lock cache files.
  31. ;;
  32. ;; See caveats and feedback below.
  33. ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34.  
  35. ;; Installation:
  36. ;; 
  37. ;; Put in your ~/.emacs:
  38. ;;
  39. ;; (setq font-lock-support-mode 'fast-lock-mode)
  40. ;;
  41. ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42. ;; so-called "gaudier" fontification regexps on big files without frustration).
  43. ;;
  44. ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45. ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46. ;; will be loaded from that file instead of being generated by Font Lock code.
  47.  
  48. ;; Caveats:
  49. ;;
  50. ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51. ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52. ;;
  53. ;; Version control packages are likely to stamp all over file modification
  54. ;; times.  Therefore the act of checking out may invalidate a cache.
  55.  
  56. ;; History:
  57. ;;
  58. ;; 0.02--1.00:
  59. ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  60. ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  61. ;; 1.00--1.01:
  62. ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  63. ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  64. ;; - Moved save-all conditions to `fast-lock-save-cache'
  65. ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  66. ;; 1.01--2.00: complete rewrite---not worth the space to document
  67. ;; - Changed structure of text properties cache and threw out file mod checks
  68. ;; 2.00--2.01:
  69. ;; - Made `condition-case' forms understand `quit'. 
  70. ;; - Made `fast-lock' require `font-lock'
  71. ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  72. ;; 2.01--3.00:
  73. ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  74. ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  75. ;; - Removed `fast-lock-read-others'
  76. ;; - Made `fast-lock-read-cache' ignore cache owner
  77. ;; - Made `fast-lock-save-cache-external' create cache directory
  78. ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  79. ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  80. ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  81. ;; - Package now provides itself
  82. ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  83. ;; - Lucid: Use `list-faces' for `face-list'
  84. ;; - Lucid: Added `set-text-properties'
  85. ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  86. ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  87. ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  88. ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  89. ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  90. ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  91. ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  92. ;; 3.02--3.03:
  93. ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  94. ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  95. ;; 3.03--3.04:
  96. ;; - Corrected `subrp' test of Lucid code
  97. ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
  98. ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
  99. ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
  100. ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
  101. ;; 3.04--3.05:
  102. ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
  103. ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
  104. ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
  105. ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
  106. ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
  107. ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
  108. ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
  109. ;; - XEmacs: Removed `list-faces' `defalias'
  110. ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
  111. ;; - Added `fast-lock-submit-bug-report'
  112. ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
  113. ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
  114. ;; - Made `fast-lock-save-cache-data' output a message if save attempted
  115. ;; - Made `fast-lock-cache-data' output a message if load attempted
  116. ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
  117. ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
  118. ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
  119. ;; - Added `fast-lock-save-events'
  120. ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
  121. ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
  122. ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
  123. ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
  124. ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
  125. ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
  126. ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
  127. ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
  128. ;; - Added `fast-lock-after-fontify-buffer'
  129. ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
  130. ;; - Made `fast-lock-get-face-properties' functions use it
  131. ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
  132. ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
  133. ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
  134. ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
  135. ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
  136. ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
  137. ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
  138. ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
  139. ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
  140. ;; 3.06--3.07:
  141. ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
  142. ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
  143. ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
  144. ;; 3.07--3.08:
  145. ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
  146. ;; 3.08--3.09:
  147. ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
  148. ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
  149. ;; - Added `fast-lock-after-unfontify-buffer'
  150. ;; 3.09--3.10:
  151. ;; - Rewrite for Common Lisp macros
  152. ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
  153. ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
  154. ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
  155. ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
  156. ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
  157. ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
  158. ;; 3.10--3.11:
  159. ;; - Made `fast-lock-get-face-properties' cope with face lists
  160. ;; - Added `fast-lock-verbose'
  161. ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
  162. ;; - Removed `fast-lock-submit-bug-report' and bade farewell
  163. ;; 3.10--3.11:
  164.  
  165. ;;; Code:
  166.  
  167. (require 'font-lock)
  168.  
  169. ;; Make sure fast-lock.el is supported.
  170. (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
  171.     (error "`fast-lock' was written for long file name systems"))
  172.  
  173. (eval-when-compile
  174.   ;;
  175.   ;; We don't do this at the top-level as we only use non-autoloaded macros.
  176.   (require 'cl)
  177.   ;;
  178.   ;; I prefer lazy code---and lazy mode.
  179.   (setq byte-compile-dynamic t byte-compile-dynamic-docstrings t)
  180.   ;; But, we make sure that the code is as zippy as can be.
  181.   (setq byte-optimize t)
  182.   ;;
  183.   ;; We use this to preserve or protect things when modifying text properties.
  184.   (defmacro save-buffer-state (varlist &rest body)
  185.     "Bind variables according to VARLIST and eval BODY restoring buffer state."
  186.     (` (let* ((,@ (append varlist
  187.            '((modified (buffer-modified-p))
  188.              (inhibit-read-only t) (buffer-undo-list t)
  189.              before-change-functions after-change-functions
  190.              deactivate-mark buffer-file-name buffer-file-truename))))
  191.      (,@ body)
  192.      (when (and (not modified) (buffer-modified-p))
  193.        (set-buffer-modified-p nil)))))
  194.   (put 'save-buffer-state 'lisp-indent-function 1)
  195.   ;;
  196.   ;; We use this to verify that a face should be saved.
  197.   (defmacro fast-lock-save-facep (face)
  198.     "Return non-nil if FACE is one of `fast-lock-save-faces'."
  199.     (` (or (null fast-lock-save-faces)
  200.        (if (symbolp (, face))
  201.            (memq (, face) fast-lock-save-faces)
  202.          (let ((faces (, face)))
  203.            (while (unless (memq (car faces) fast-lock-save-faces)
  204.             (setq faces (cdr faces))))
  205.            faces))))))
  206.  
  207. ;(defun fast-lock-submit-bug-report ()
  208. ;  "Submit via mail a bug report on fast-lock.el."
  209. ;  (interactive)
  210. ;  (let ((reporter-prompt-for-summary-p t))
  211. ;    (reporter-submit-bug-report "simon@gnu.ai.mit.edu" "fast-lock 3.11.01"
  212. ;     '(fast-lock-cache-directories fast-lock-minimum-size
  213. ;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
  214. ;       fast-lock-verbose)
  215. ;     nil nil
  216. ;     (concat "Hi Si.,
  217. ;
  218. ;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
  219. ;know how to make a clear and unambiguous report.  To reproduce the bug:
  220. ;
  221. ;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
  222. ;In the `*scratch*' buffer, evaluate:"))))
  223.  
  224. (defvar fast-lock-mode nil)        ; Whether we are turned on.
  225. (defvar fast-lock-cache-timestamp nil)    ; For saving/reading.
  226. (defvar fast-lock-cache-filename nil)    ; For deleting.
  227.  
  228. ;; User Variables:
  229.  
  230. (defgroup fast-lock nil
  231.   "Automagic text properties caching for fast Font Lock mode"
  232.   :group 'faces)
  233.  
  234.  
  235. (defcustom fast-lock-cache-directories '("." "~/.emacs-flc")
  236. ; - `internal', keep each file's Font Lock cache file in the same file.
  237. ; - `external', keep each file's Font Lock cache file in the same directory.
  238.   "*Directories in which Font Lock cache files are saved and read.
  239. Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
  240. DIR is a directory name (relative or absolute) and REGEXP is a regexp.
  241.  
  242. An attempt will be made to save or read Font Lock cache files using these items
  243. until one succeeds (i.e., until a readable or writable one is found).  If an
  244. item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
  245. For example:
  246.  
  247.  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
  248.    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
  249.     =>
  250.  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
  251.  
  252. would cause a file's current directory to be used if the file is under your
  253. home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'."
  254.   :type '(repeat (choice (cons regexp directory) directory))
  255.   :group 'fast-lock)
  256.  
  257. (defcustom fast-lock-minimum-size (* 25 1024)
  258.   "*Minimum size of a buffer for cached fontification.
  259. Only buffers more than this can have associated Font Lock cache files saved.
  260. If nil, means cache files are never created.
  261. If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
  262. where MAJOR-MODE is a symbol or t (meaning the default).  For example:
  263.  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
  264. means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
  265. for buffers in Rmail mode, and size is irrelevant otherwise."
  266.   :type '(choice (integer :tag "Size") (repeat (cons (symbol :tag "Major Mode")
  267.                             (integer :tag "Size"))))
  268.   :group 'fast-lock)
  269.  
  270. (defcustom fast-lock-save-events '(kill-buffer kill-emacs)
  271.   "*Events under which caches will be saved.
  272. Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
  273. If concurrent editing sessions use the same associated cache file for a file's
  274. buffer, then you should add `save-buffer' to this list."
  275.   :type '(set (const kill-buffer) (const save-buffer) (const kill-emacs))
  276.   :group 'fast-lock)
  277.  
  278. (defcustom fast-lock-save-others t
  279.   "*If non-nil, save Font Lock cache files irrespective of file owner.
  280. If nil, means only buffer files known to be owned by you can have associated
  281. Font Lock cache files saved.  Ownership may be unknown for networked files."
  282.   :type 'boolean
  283.   :group 'fast-lock)
  284.  
  285. (defvar fast-lock-save-faces
  286.   (when (save-match-data (string-match "XEmacs" (emacs-version)))
  287.     ;; XEmacs uses extents for everything, so we have to pick the right ones.
  288.     font-lock-face-list)
  289.   "Faces that will be saved in a Font Lock cache file.
  290. If nil, means information for all faces will be saved.")
  291.  
  292. (defcustom fast-lock-verbose font-lock-verbose
  293.   "*If non-nil, means show status messages for cache processing.
  294. If a number, only buffers greater than this size have processing messages."
  295.   :type '(choice integer boolean)
  296.   :group 'fast-lock)
  297.  
  298. ;; User Functions:
  299.  
  300. ;;;###autoload
  301. (defun fast-lock-mode (&optional arg)
  302.   "Toggle Fast Lock mode.
  303. With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
  304. is associated with a file.  Enable it automatically in your `~/.emacs' by:
  305.  
  306.  (setq font-lock-support-mode 'fast-lock-mode)
  307.  
  308. If Fast Lock mode is enabled, and the current buffer does not contain any text
  309. properties, any associated Font Lock cache is used if its timestamp matches the
  310. buffer's file, and its `font-lock-keywords' match those that you are using.
  311.  
  312. Font Lock caches may be saved:
  313. - When you save the file's buffer.
  314. - When you kill an unmodified file's buffer.
  315. - When you exit Emacs, for all unmodified or saved buffers.
  316. Depending on the value of `fast-lock-save-events'.
  317. See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
  318.  
  319. Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
  320.  
  321. Various methods of control are provided for the Font Lock cache.  In general,
  322. see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
  323. For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
  324. `fast-lock-save-others' and `fast-lock-save-faces'."
  325.   (interactive "P")
  326.   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
  327.   ;; but many packages temporarily wrap that to nil when doing their own thing.
  328.   (set (make-local-variable 'fast-lock-mode)
  329.        (and buffer-file-truename
  330.         (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
  331.         (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
  332.   (if (and fast-lock-mode (not font-lock-mode))
  333.       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
  334.       (let ((font-lock-support-mode 'fast-lock-mode))
  335.     (font-lock-mode t))
  336.     ;; Let's get down to business.
  337.     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
  338.     (set (make-local-variable 'fast-lock-cache-filename) nil)
  339.     (when (and fast-lock-mode (not font-lock-fontified))
  340.       (fast-lock-read-cache))))
  341.  
  342. (defun fast-lock-read-cache ()
  343.   "Read the Font Lock cache for the current buffer.
  344.  
  345. The following criteria must be met for a Font Lock cache file to be read:
  346. - Fast Lock mode must be turned on in the buffer.
  347. - The buffer must not be modified.
  348. - The buffer's `font-lock-keywords' must match the cache's.
  349. - The buffer file's timestamp must match the cache's.
  350. - Criteria imposed by `fast-lock-cache-directories'.
  351.  
  352. See `fast-lock-mode'."
  353.   (interactive)
  354.   (let ((directories fast-lock-cache-directories)
  355.     (modified (buffer-modified-p)) (inhibit-read-only t)
  356.     (fontified font-lock-fontified))
  357.     (set (make-local-variable 'font-lock-fontified) nil)
  358.     ;; Keep trying directories until fontification is turned off.
  359.     (while (and directories (not font-lock-fontified))
  360.       (let ((directory (fast-lock-cache-directory (car directories) nil)))
  361.     (condition-case nil
  362.         (when directory
  363.           (setq fast-lock-cache-filename (fast-lock-cache-name directory))
  364.           (when (file-readable-p fast-lock-cache-filename)
  365.         (load fast-lock-cache-filename t t t)))
  366.       (error nil) (quit nil))
  367.     (setq directories (cdr directories))))
  368.     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
  369.     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
  370.     ;; of `fast-lock-cache-timestamp'.)
  371.     (set-buffer-modified-p modified)
  372.     (unless font-lock-fontified
  373.       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
  374.  
  375. (defun fast-lock-save-cache (&optional buffer)
  376.   "Save the Font Lock cache of BUFFER or the current buffer.
  377.  
  378. The following criteria must be met for a Font Lock cache file to be saved:
  379. - Fast Lock mode must be turned on in the buffer.
  380. - The event must be one of `fast-lock-save-events'.
  381. - The buffer must be at least `fast-lock-minimum-size' bytes long.
  382. - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
  383. - The buffer must contain at least one `face' text property.
  384. - The buffer must not be modified.
  385. - The buffer file's timestamp must be the same as the file's on disk.
  386. - The on disk file's timestamp must be different than the buffer's cache.
  387. - Criteria imposed by `fast-lock-cache-directories'.
  388.  
  389. See `fast-lock-mode'."
  390.   (interactive)
  391.   (save-excursion
  392.     (when buffer
  393.       (set-buffer buffer))
  394.     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
  395.       (file-timestamp (visited-file-modtime)) (saved nil))
  396.       (when (and fast-lock-mode
  397.          ;;
  398.          ;; "Only save if the buffer matches the file, the file has
  399.          ;; changed, and it was changed by the current emacs session."
  400.          ;;
  401.          ;; Only save if the buffer is not modified,
  402.          ;; (i.e., so we don't save for something not on disk)
  403.          (not (buffer-modified-p))
  404.          ;; and the file's timestamp is the same as the buffer's,
  405.          ;; (i.e., someone else hasn't written the file in the meantime)
  406.          (verify-visited-file-modtime (current-buffer))
  407.          ;; and the file's timestamp is different from the cache's.
  408.          ;; (i.e., a save has occurred since the cache was read)
  409.          (not (equal fast-lock-cache-timestamp file-timestamp))
  410.          ;;
  411.          ;; Only save if user's restrictions are satisfied.
  412.          (and min-size (>= (buffer-size) min-size))
  413.          (or fast-lock-save-others
  414.          (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
  415.          ;;
  416.          ;; Only save if there are `face' properties to save.
  417.          (text-property-not-all (point-min) (point-max) 'face nil))
  418.     ;;
  419.     ;; Try each directory until we manage to save or the user quits.
  420.     (let ((directories fast-lock-cache-directories))
  421.       (while (and directories (memq saved '(nil error)))
  422.         (let* ((dir (fast-lock-cache-directory (car directories) t))
  423.            (file (and dir (fast-lock-cache-name dir))))
  424.           (when (and file (file-writable-p file))
  425.         (setq saved (fast-lock-save-cache-1 file file-timestamp)))
  426.           (setq directories (cdr directories)))))))))
  427.  
  428. ;;;###autoload
  429. (defun turn-on-fast-lock ()
  430.   "Unconditionally turn on Fast Lock mode."
  431.   (fast-lock-mode t))
  432.  
  433. ;;; API Functions:
  434.  
  435. (defun fast-lock-after-fontify-buffer ()
  436.   ;; Delete the Font Lock cache file used to restore fontification, if any.
  437.   (when fast-lock-cache-filename
  438.     (if (file-writable-p fast-lock-cache-filename)
  439.     (delete-file fast-lock-cache-filename)
  440.       (message "File %s font lock cache cannot be deleted" (buffer-name))))
  441.   ;; Flag so that a cache will be saved later even if the file is never saved.
  442.   (setq fast-lock-cache-timestamp nil))
  443.  
  444. (defalias 'fast-lock-after-unfontify-buffer
  445.   'ignore)
  446.  
  447. ;; Miscellaneous Functions:
  448.  
  449. (defun fast-lock-save-cache-after-save-file ()
  450.   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
  451.   (when (memq 'save-buffer fast-lock-save-events)
  452.     (fast-lock-save-cache)))
  453.  
  454. (defun fast-lock-save-cache-before-kill-buffer ()
  455.   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
  456.   (when (memq 'kill-buffer fast-lock-save-events)
  457.     (fast-lock-save-cache)))
  458.  
  459. (defun fast-lock-save-caches-before-kill-emacs ()
  460.   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
  461.   (when (memq 'kill-emacs fast-lock-save-events)
  462.     (mapcar 'fast-lock-save-cache (buffer-list))))
  463.  
  464. (defun fast-lock-cache-directory (directory create)
  465.   "Return usable directory based on DIRECTORY.
  466. Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
  467. created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
  468. See `fast-lock-cache-directories'."
  469.   (let ((dir
  470.      (cond ((not buffer-file-name)
  471.         ;; Should never be nil, but `crypt++' screws it up.
  472.         nil)
  473.            ((stringp directory)
  474.         ;; Just a directory.
  475.         directory)
  476.            (t
  477.         ;; A directory iff the file name matches the regexp.
  478.         (let ((bufile (expand-file-name buffer-file-truename))
  479.               (case-fold-search nil))
  480.           (when (save-match-data (string-match (car directory) bufile))
  481.             (cdr directory)))))))
  482.     (cond ((not dir)
  483.        nil)
  484.       ((file-accessible-directory-p dir)
  485.        dir)
  486.       (create
  487.        (condition-case nil
  488.            (progn (make-directory dir t) dir)
  489.          (error nil))))))
  490.  
  491. ;; If you are wondering why we only hash if the directory is not ".", rather
  492. ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
  493. ;; relative cache directories (that are not ".") then it is possible that more
  494. ;; than one file would have the same cache name in that directory, if the luser
  495. ;; made a link from one relative cache directory to another.  (Phew!)
  496. (defun fast-lock-cache-name (directory)
  497.   "Return full cache path name using caching DIRECTORY.
  498. If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
  499. Otherwise, the path name is constructed from DIRECTORY and the buffer's true
  500. abbreviated file name, with all `/' characters in the name replaced with `#'
  501. characters, and appended with `.flc'.
  502.  
  503. If the same file has different cache path names when edited on different
  504. machines, e.g., on one machine the cache file name has the prefix `#home',
  505. perhaps due to automount, try putting in your `~/.emacs' something like:
  506.  
  507.  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
  508.  
  509. Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
  510.  
  511. See `fast-lock-cache-directory'."
  512.   (if (string-equal directory ".")
  513.       (concat buffer-file-name ".flc")
  514.     (let* ((bufile (expand-file-name buffer-file-truename))
  515.        (chars-alist
  516.         (if (eq system-type 'emx)
  517.         '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
  518.           '((?/ . (?#)) (?# . (?# ?#)))))
  519.        (mapchars
  520.         (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
  521.       (concat
  522.        (file-name-as-directory (expand-file-name directory))
  523.        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
  524.        ".flc"))))
  525.  
  526. ;; Font Lock Cache Processing Functions:
  527.  
  528. (defun fast-lock-save-cache-1 (file timestamp)
  529.   ;; Save the FILE with the TIMESTAMP as:
  530.   ;; (fast-lock-cache-data Version=2 TIMESTAMP font-lock-keywords PROPERTIES).
  531.   ;; Returns non-nil if a save was attempted to a writable cache file.
  532.   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
  533.     (verbose (if (numberp fast-lock-verbose)
  534.              (> (buffer-size) fast-lock-verbose)
  535.            fast-lock-verbose))
  536.     (saved t))
  537.     (if verbose (message "Saving %s font lock cache..." (buffer-name)))
  538.     (condition-case nil
  539.     (save-excursion
  540.       (print (list 'fast-lock-cache-data 2
  541.                (list 'quote timestamp)
  542.                (list 'quote font-lock-keywords)
  543.                (list 'quote (fast-lock-get-face-properties)))
  544.          tpbuf)
  545.       (set-buffer tpbuf)
  546.       (write-region (point-min) (point-max) file nil 'quietly)
  547.       (setq fast-lock-cache-timestamp timestamp
  548.         fast-lock-cache-filename file))
  549.       (error (setq saved 'error)) (quit (setq saved 'quit)))
  550.     (kill-buffer tpbuf)
  551.     (if verbose (message "Saving %s font lock cache...%s" (buffer-name)
  552.              (cond ((eq saved 'error) "failed")
  553.                    ((eq saved 'quit) "aborted")
  554.                    (t "done"))))
  555.     ;; We return non-nil regardless of whether a failure occurred.
  556.     saved))
  557.  
  558. (defun fast-lock-cache-data (version timestamp keywords properties
  559.                  &rest ignored)
  560.   ;; Change from (HIGH LOW) for back compatibility.  Remove for version 3!
  561.   (when (consp (cdr-safe timestamp))
  562.     (setcdr timestamp (nth 1 timestamp)))
  563.   ;; Compile KEYWORDS and `font-lock-keywords' in case one is and one isn't.
  564.   (let ((current font-lock-keywords))
  565.     (setq keywords (font-lock-compile-keywords keywords)
  566.       font-lock-keywords (font-lock-compile-keywords current)))
  567.   ;; Use the Font Lock cache PROPERTIES if we're using cache VERSION format 2,
  568.   ;; the current buffer's file timestamp matches the TIMESTAMP, and the current
  569.   ;; buffer's font-lock-keywords are the same as KEYWORDS.
  570.   (let ((buf-timestamp (visited-file-modtime))
  571.     (verbose (if (numberp fast-lock-verbose)
  572.              (> (buffer-size) fast-lock-verbose)
  573.            fast-lock-verbose))
  574.     (loaded t))
  575.     (if (or (/= version 2)
  576.         (buffer-modified-p)
  577.         (not (equal timestamp buf-timestamp))
  578.         (not (equal keywords font-lock-keywords)))
  579.     (setq loaded nil)
  580.       (if verbose (message "Loading %s font lock cache..." (buffer-name)))
  581.       (condition-case nil
  582.       (fast-lock-set-face-properties properties)
  583.     (error (setq loaded 'error)) (quit (setq loaded 'quit)))
  584.       (if verbose (message "Loading %s font lock cache...%s" (buffer-name)
  585.                (cond ((eq loaded 'error) "failed")
  586.                  ((eq loaded 'quit) "aborted")
  587.                  (t "done")))))
  588.     (setq font-lock-fontified (eq loaded t)
  589.       fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
  590.  
  591. ;; Text Properties Processing Functions:
  592.  
  593. ;; This is fast, but fails if adjacent characters have different `face' text
  594. ;; properties.  Maybe that's why I dropped it in the first place?
  595. ;(defun fast-lock-get-face-properties ()
  596. ;  "Return a list of all `face' text properties in the current buffer.
  597. ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
  598. ;where VALUE is a `face' property value and STARTx and ENDx are positions."
  599. ;  (save-restriction
  600. ;    (widen)
  601. ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
  602. ;      (limit (point-max)) end properties value cell)
  603. ;      (while start
  604. ;    (setq end (next-single-property-change start 'face nil limit)
  605. ;          value (get-text-property start 'face))
  606. ;    ;; Make, or add to existing, list of regions with same `face'.
  607. ;    (if (setq cell (assq value properties))
  608. ;        (setcdr cell (cons start (cons end (cdr cell))))
  609. ;      (setq properties (cons (list value start end) properties)))
  610. ;    (setq start (next-single-property-change end 'face)))
  611. ;      properties)))
  612.  
  613. ;; This is slow, but copes if adjacent characters have different `face' text
  614. ;; properties, but fails if they are lists.
  615. ;(defun fast-lock-get-face-properties ()
  616. ;  "Return a list of all `face' text properties in the current buffer.
  617. ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
  618. ;where VALUE is a `face' property value and STARTx and ENDx are positions.
  619. ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
  620. ;  (save-restriction
  621. ;    (widen)
  622. ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
  623. ;      properties regions face start end)
  624. ;      (while faces
  625. ;    (setq face (car faces) faces (cdr faces) regions () end (point-min))
  626. ;    ;; Make a list of start/end regions with `face' property face.
  627. ;    (while (setq start (text-property-any end limit 'face face))
  628. ;      (setq end (or (text-property-not-all start limit 'face face) limit)
  629. ;        regions (cons start (cons end regions))))
  630. ;    ;; Add `face' face's regions, if any, to properties.
  631. ;    (when regions
  632. ;      (push (cons face regions) properties)))
  633. ;      properties)))
  634.  
  635. (defun fast-lock-get-face-properties ()
  636.   "Return a list of all `face' text properties in the current buffer.
  637. Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
  638. where VALUE is a `face' property value and STARTx and ENDx are positions."
  639.   (save-restriction
  640.     (widen)
  641.     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
  642.       end properties value cell)
  643.       (while start
  644.     (setq end (next-single-property-change start 'face nil (point-max))
  645.           value (get-text-property start 'face))
  646.     ;; Make, or add to existing, list of regions with same `face'.
  647.     (cond ((setq cell (assoc value properties))
  648.            (setcdr cell (cons start (cons end (cdr cell)))))
  649.           ((fast-lock-save-facep value)
  650.            (push (list value start end) properties)))
  651.     (setq start (text-property-not-all end (point-max) 'face nil)))
  652.       properties)))
  653.  
  654. (defun fast-lock-set-face-properties (properties)
  655.   "Set all `face' text properties to PROPERTIES in the current buffer.
  656. Any existing `face' text properties are removed first.
  657. See `fast-lock-get-face-properties' for the format of PROPERTIES."
  658.   (save-buffer-state (plist regions)
  659.     (save-restriction
  660.       (widen)
  661.       (font-lock-unfontify-region (point-min) (point-max))
  662.       (while properties
  663.     (setq plist (list 'face (car (car properties)))
  664.           regions (cdr (car properties))
  665.           properties (cdr properties))
  666.     ;; Set the `face' property for each start/end region.
  667.     (while regions
  668.       (set-text-properties (nth 0 regions) (nth 1 regions) plist)
  669.       (setq regions (nthcdr 2 regions)))))))
  670.  
  671. ;; Functions for XEmacs:
  672.  
  673. (when (save-match-data (string-match "XEmacs" (emacs-version)))
  674.   ;;
  675.   ;; It would be better to use XEmacs' `map-extents' over extents with a
  676.   ;; `font-lock' property, but `face' properties are on different extents.
  677.   (defun fast-lock-get-face-properties ()
  678.     "Return a list of all `face' text properties in the current buffer.
  679. Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
  680. where VALUE is a `face' property value and STARTx and ENDx are positions.
  681. Only those `face' VALUEs in `fast-lock-save-faces' are returned."
  682.     (save-restriction
  683.       (widen)
  684.       (let ((properties ()) cell)
  685.     (map-extents
  686.      (function (lambda (extent ignore)
  687.         (let ((value (extent-face extent)))
  688.           ;; We're only interested if it's one of `fast-lock-save-faces'.
  689.           (when (and value (fast-lock-save-facep value))
  690.         (let ((start (extent-start-position extent))
  691.               (end (extent-end-position extent)))
  692.           ;; Make or add to existing list of regions with the same
  693.           ;; `face' property value.
  694.           (if (setq cell (assoc value properties))
  695.               (setcdr cell (cons start (cons end (cdr cell))))
  696.             (push (list value start end) properties))))
  697.           ;; Return nil to keep `map-extents' going.
  698.           nil))))
  699.     properties)))
  700.   ;;
  701.   ;; Make extents just like XEmacs' font-lock.el does.
  702.   (defun fast-lock-set-face-properties (properties)
  703.     "Set all `face' text properties to PROPERTIES in the current buffer.
  704. Any existing `face' text properties are removed first.
  705. See `fast-lock-get-face-properties' for the format of PROPERTIES."
  706.     (save-restriction
  707.       (widen)
  708.       (font-lock-unfontify-region (point-min) (point-max))
  709.       (while properties
  710.     (let ((face (car (car properties)))
  711.           (regions (cdr (car properties))))
  712.       ;; Set the `face' property, etc., for each start/end region.
  713.       (while regions
  714.         (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
  715.         (setq regions (nthcdr 2 regions)))
  716.       (setq properties (cdr properties))))))
  717.   ;;
  718.   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
  719.   (add-hook 'font-lock-after-fontify-buffer-hook
  720.         'fast-lock-after-fontify-buffer))
  721.  
  722. (unless (boundp 'font-lock-inhibit-thing-lock)
  723.   (defvar font-lock-inhibit-thing-lock nil
  724.     "List of Font Lock mode related modes that should not be turned on."))
  725.  
  726. (unless (fboundp 'font-lock-value-in-major-mode)
  727.   (defun font-lock-value-in-major-mode (alist)
  728.     ;; Return value in ALIST for `major-mode'.
  729.     (if (consp alist)
  730.     (cdr (or (assq major-mode alist) (assq t alist)))
  731.       alist)))
  732.  
  733. (unless (fboundp 'font-lock-compile-keywords)
  734.   (defalias 'font-lock-compile-keywords 'identity))
  735.  
  736. ;; Install ourselves:
  737.  
  738. (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
  739. (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
  740. (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
  741.  
  742. ;;;###autoload
  743. (when (fboundp 'add-minor-mode)
  744.   (defvar fast-lock-mode nil)
  745.   (add-minor-mode 'fast-lock-mode nil))
  746. ;;;###dont-autoload
  747. (unless (assq 'fast-lock-mode minor-mode-alist)
  748.   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
  749.  
  750. ;; Provide ourselves:
  751.  
  752. (provide 'fast-lock)
  753.  
  754. ;;; fast-lock.el ends here
  755.